模块 Queue

module Queue: sig .. end

先进先出队列。

此模块实现队列（FIFO），并进行就地修改。请参阅 下面的示例部分。

未同步访问

对队列进行未同步访问可能会导致队列状态无效。因此，必须同步对队列的并发访问（例如使用 Mutex.t）。

type !'a t

包含类型为 'a 的元素的队列类型。

exception Empty

当对空队列应用 Queue.take 或 Queue.peek 时引发。

val create : unit -> 'a t

返回一个新的队列，初始为空。

val add : 'a -> 'a t -> unit

add x q 将元素 x 添加到队列 q 的末尾。

val push : 'a -> 'a t -> unit

push 是 add 的同义词。

val take : 'a t -> 'a

take q 移除并返回队列 q 中的第一个元素，如果队列为空则引发 Queue.Empty。

val take_opt : 'a t -> 'a option

take_opt q 移除并返回队列 q 中的第一个元素，如果队列为空则返回 None。

val pop : 'a t -> 'a

pop 是 take 的同义词。

val peek : 'a t -> 'a

peek q 返回队列 q 中的第一个元素，但不将其从队列中移除，如果队列为空则引发 Queue.Empty。

val peek_opt : 'a t -> 'a option

peek_opt q 返回队列 q 中的第一个元素，但不将其从队列中移除，如果队列为空则返回 None。

val top : 'a t -> 'a

top 是 peek 的同义词。

val clear : 'a t -> unit

丢弃队列中的所有元素。

val copy : 'a t -> 'a t

返回给定队列的副本。

val is_empty : 'a t -> bool

如果给定队列为空，则返回 true，否则返回 false。

val length : 'a t -> int

返回队列中的元素数量。

val iter : ('a -> unit) -> 'a t -> unit

iter f q 依次将 f 应用于 q 中的所有元素，从最近进入的元素到最先进入的元素。队列本身保持不变。

val fold : ('acc -> 'a -> 'acc) -> 'acc -> 'a t -> 'acc

fold f accu q 等效于 List.fold_left f accu l，其中 l 是 q 的元素列表。队列保持不变。

val transfer : 'a t -> 'a t -> unit

transfer q1 q2 将 q1 中的所有元素添加到队列 q2 的末尾，然后清除 q1。它等效于序列 iter (fun x -> add x q2) q1; clear q1，但运行时间恒定。

迭代器

val to_seq : 'a t -> 'a Seq.t

以从前往后的顺序迭代队列。如果在迭代期间修改队列，则行为未指定。

val add_seq : 'a t -> 'a Seq.t -> unit

将序列中的元素添加到队列的末尾。

val of_seq : 'a Seq.t -> 'a t

从序列创建队列。

示例

基本示例

一个基本的示例

    # let q = Queue.create ()
    val q : '_weak1 Queue.t = <abstr>


    # Queue.push 1 q; Queue.push 2 q; Queue.push 3 q
    - : unit = ()

    # Queue.length q
    - : int = 3

    # Queue.pop q
    - : int = 1

    # Queue.pop q
    - : int = 2

    # Queue.pop q
    - : int = 3

    # Queue.pop q
    Exception: Stdlib.Queue.Empty.

遍历图

有关更详细的示例，队列的经典算法用途是实现图的 BFS（广度优先搜索）。

     type graph = {
       edges: (int, int list) Hashtbl.t
     }

    (* Search in graph [g] using BFS, starting from node [start].
       It returns the first node that satisfies [p], or [None] if
       no node reachable from [start] satisfies [p].
    *)
    let search_for ~(g:graph) ~(start:int) (p:int -> bool) : int option =
      let to_explore = Queue.create() in
      let explored = Hashtbl.create 16 in

      Queue.push start to_explore;
      let rec loop () =
        if Queue.is_empty to_explore then None
        else
          (* node to explore *)
          let node = Queue.pop to_explore in
          explore_node node

      and explore_node node =
        if not (Hashtbl.mem explored node) then (
          if p node then Some node (* found *)
          else (
            Hashtbl.add explored node ();
            let children =
              Hashtbl.find_opt g.edges node
              |> Option.value ~default:[]
            in
            List.iter (fun child -> Queue.push child to_explore) children;
            loop()
          )
        ) else loop()
      in
      loop()

    (* a sample graph *)
    let my_graph: graph =
      let edges =
        List.to_seq [
          1, [2;3];
          2, [10; 11];
          3, [4;5];
          5, [100];
          11, [0; 20];
        ]
        |> Hashtbl.of_seq
      in {edges}

    # search_for ~g:my_graph ~start:1 (fun x -> x = 30)
    - : int option = None

    # search_for ~g:my_graph ~start:1 (fun x -> x >= 15)
    - : int option = Some 20

    # search_for ~g:my_graph ~start:1 (fun x -> x >= 50)
    - : int option = Some 100