使用 yaml 反序列化和后处理 YAML 数据
任务
数据格式 / YAML / 反序列化和后处理 YAML 数据
反序列化一个 YAML 文件，其结构不直接映射到某些 OCaml 类型。
使用的 Opam 包
- yaml 测试版本：3.2.0 — 使用的库：yaml
- ppx_deriving_yaml 测试版本：0.2.2 — 使用的库：ppx_deriving_yaml
代码
此 YAML 字符串包含一个配料列表，其中配料表示为 YAML 对象，键表示名称，值表示数量。
let yaml_string = {|
french name: pâte sucrée
ingredients:
- flour: 250
- butter: 100
- sugar: 100
- egg: 50
- salt: 5
steps:
- soften butter
- add sugar
- add egg and salt
- add flour
|}
[@@deriving of_yaml] 属性使 ppx_deriving_yaml 库生成函数 ingredient_of_yaml : Yaml.value -> (ingredient, [> `Msg of string]) result。
type ingredient = {
name: string;
weight: int;
} [@@deriving of_yaml]
[@@deriving of_yaml] 属性使 ppx_deriving_yaml 库生成函数 recipe_of_yaml : Yaml.value -> (ingredient, [> `Msg of string]) result。
type recipe = {
name: string; [@key "french name"]
ingredients: ingredient list;
steps: string list;
} [@@deriving of_yaml]
由于 YAML 文件的结构与 recipe 类型不完全匹配，因此我们 (1) 将 YAML 文件解析为 yaml 包的内部表示 Yaml.value，然后 (2) 更改结构以匹配 recipe 类型，以便我们可以使用 recipe_of_yaml 函数。
函数 add_keys 和 at_ingredients 执行此后处理。
let add_keys = function
| `O [(name, `Float weight)] ->
`O [
("name", `String name);
("weight", `Float weight);
]
| v -> v
let at_ingredients f = function
| `O [
("french name", `String name);
("ingredients", `A ingredients);
("steps", `A steps)
] -> `O [
("french name", `String name);
("ingredients",
Yaml.Util.map_exn f (`A ingredients));
("steps", `A steps);
]
| v -> v
解析、后处理并将 YAML 字符串转换为 recipe 类型的 OCaml 值。
let pate_sucree =
yaml_string
|> Yaml.of_string
|> Result.map (at_ingredients add_keys)
|> fun yaml -> Result.bind yaml recipe_of_yaml