使用标准库进行基本文件和目录操作

任务

文件系统 / 基本文件和目录操作

存在、复制、移动（重命名）、删除、更改目录、列出目录、删除目录。

未使用任何包

此食谱仅使用 OCaml 标准库.

代码

通过测试文件名来检查文件或目录是否存在。

let file_exists filename =
  if Sys.file_exists filename then
    Printf.printf "The file/directory '%s' exists.\n"
      filename
  else
    Printf.printf "The file/directory '%s' does not \
      exist.\n" filename

检查给定的路径是目录还是文件。

let check_if_directory path =
  if Sys.file_exists path then
    (if Sys.is_directory path then
       Printf.printf "'%s' is a directory.\n" path
     else
       Printf.printf "'%s' is a file.\n" path)
  else
    Printf.printf "'%s' does not exist.\n" path

将源文件的内容复制到目标文件。

let copy_file src dst =
  let content =
    In_channel.with_open_text src In_channel.input_all
  in
  Out_channel.with_open_text dst (fun out_channel ->
      Out_channel.output_string out_channel content);
  Printf.printf "Copied '%s' to '%s'.\n" src dst

将文件移动（重命名）到新的位置或名称。

let move_file src dst =
  if Sys.file_exists src then (
    Sys.rename src dst;
    Printf.printf "Moved '%s' to '%s'.\n" src dst
  ) else
    Printf.printf "File '%s' does not exist.\n" src

如果存在且不是目录，则删除指定文件。

let delete_file filename =
  if Sys.file_exists filename &&
     not (Sys.is_directory filename) then (
    Sys.remove filename;
    Printf.printf "Deleted file '%s'.\n" filename
  ) else
    Printf.printf "File '%s' does not exist or is \
      a directory.\n" filename

将当前工作目录更改为指定的目录路径。

let change_directory dir =
  if Sys.file_exists dir && Sys.is_directory dir then (
    Sys.chdir dir;
    Printf.printf "Changed current directory to '%s'.\n"
      dir
  ) else
    Printf.printf "'%s' does not exist or is not \
      a directory.\n" dir

如果存在，则删除指定目录。

let delete_directory dir =
  if Sys.file_exists dir && Sys.is_directory dir then (
    Sys.rmdir dir;
    Printf.printf "Deleted directory '%s'.\n" dir
  ) else
    Printf.printf "'%s' does not exist or is not \
      a directory.\n" dir

列出指定目录中的所有文件和目录。打印内容的名称，如果路径不存在或不是目录，则打印错误。

let list_directory dir =
  if Sys.file_exists dir && Sys.is_directory dir then (
    let file_array = Sys.readdir dir in
    Printf.printf "Contents of directory '%s':\n" dir;
    Array.iter (fun filename ->
      Printf.printf "  %s\n" filename) file_array
  ) else
    Printf.printf "'%s' does not exist or is not \
      a directory.\n" dir

讨论

食谱不起作用？ 注释不清楚或过时？

打开一个问题 或 为这个食谱贡献代码！